Excel. Трюки и эффекты
Шрифт:
Приведенная в листинге 2.22 функция отнюдь не претендует на то, чтобы быть эталоном в порядке классификации сообщений от элементов управления. Иногда бывает полезно сразу классифицировать сообщения не по элементам управления, которые их прислали, а по типу. К тому же в ряде случаев можно предусмотреть один обработчик сообщений сразу для нескольких элементов управления, например для группы переключателей. В таком случае полезным окажется параметр 1 Par am сообщения WM_COMMAND.
Кстати, размер исполняемого файла этого приложения всего 19 Кбайт.
2.4. Стандартные диалоговые окна Windows
Теперь рассмотрим, как можно только при помощи функций Windows API вызывать некоторые распространенные диалоговые окна. Чтобы использовать API-функции и структуры с информацией для этих диалоговых окон, необходимо подключить
• CommDlg – для окон открытия/сохранения файла, выбора цвета и шрифта, поиска и замены текста;
• ShlObj и ActiveX – для окна выбора папки (второй модуль нужен для дос тупа к интерфейсу IMalloc, зачем – будет рассказано далее);
• Windows – помимо объявления основных структур и API-функций, этот модуль содержит объявления функций для работы с окнами подключения и отключения от сетевого ресурса (сетевого диска);
• ShellAPI – для системного окна О программе.
Вариант использования рассматриваемых в этом разделе диалоговых окон приведен в подразд. «Демонстрационное приложение».
Примечание
В приведенных далее примерах вызова диалоговых окон можно увидеть не объявленные, но используемые в программах переменные hApplnst и hParentWnd. Подразумевается, что это глобальные переменные, которые инициализируются вне процедур и функций, приведенных в примерах. Для инициализации этих переменных можно также написать специальную процедуру, например с именем I nit, в которую и передавать значения для hParentWnd и hApplnst.
Окно открытия/сохранения файла
Чтобы воспользоваться возможностями окна открытия файла, достаточно задействовать листинг 2.23.
Листинг 2.23.
Окно открытия файла
function ShowOpen(strFilter: string; nFilterIndex: Integer = 0;
strInitFileName: string = \'\
var
ofn: OPENFILENAME;
begin
ZeroMemory(Addr(ofn), SizeOf(ofn));
//Формирование буфера (260 символов)
SetLength(strInitFileName, MAX_PATH);
PrepareFilterString(strFilter);
//Заполнение структуры для диалога
ofn.lStructSize := SizeOf(ofn);
ofn.hWndOwner := hParentWnd;
ofn.hInstance := hAppInst;
ofn.lpstrFilter := PAnsiChar(strFilter);
ofn.nFilterIndex := nFilterIndex;
ofn.lpstrFile := PAnsiChar(strInitFileName);
ofn.nMaxFile := MAX_PATH;
ofn.lpstrTitle := pAnsiChar(strTitle);
ofn.Flags := OFN_FILEMUSTEXIST or OFN_PATHMUSTEXIST or
OFN_HIDEREADONLY;
//Отображение окна диалога и обработка результата
if (GetOpenFileName(ofn) = True) then
ShowOpen := ofn.lpstrFile;
end;
Приведенная в листинге 2.23 функция возвращает не пустую строку – полный путь файла в случае, если пользователь выбрал или ввел имя файла. Здесь главной трудностью является заполнение довольно большой структуры OPENFILENAME. В данном примере используются только базовые возможности диалога открытия файла и лишь некоторые из поддерживаемых им флагов (поле Flags):
• OFN_FILEMUSTEXIST – при успешном завершении работы диалогового окна можно быть уверенным, что результирующий путь является путем существующего файла;
• OFN_PATHMUSTEXI ST – не дает ввести имя файла в несуществующей папке (например, при вводе с:\docs\mydocl.doc, если папки docs не существует, будет выдано соответствующее сообщение);
• OFNHIDEREADONLY – не показывать флажок Только для чтения.
Отдельно рассмотрим, зачем в приведенном примере вызывается дополнительная функция PrepareFilterString (листинг 2.24).
Листинг 2.24.
Преобразование строки фильтра
procedure PrepareFilterString(var strFilter: string);
var
i: Integer;
begin
for i := 1 to length(strFilter) do
if (strFilter[i] = \'|\') then strFilter[i] := #0;
end;
Дело в том, что при задании фильтров (поле IpstrFile) требуется, чтобы каждое их название и обозначение были отделены символом #0, а за последним фильтром шла последовательность из двух нулевых символов. На практике задавать строку
из нескольких фильтров в следующем виде не особо удобно:\'Текстовые файлы\' + #0 + \'*.txt\' + #0 + \'Все файлы\' + \'*.*\' + #0 + #0
Поэтому часто применяются другие разделители, которые впоследствии преобразуются в символы #0. В нашем случае в качестве разделителя используется символ |, поэтому приведенная выше строка фильтра может быть записана так:
\'Текстовые файлы|*.txt|Все файлы|*.*||\'
Согласитесь, что получилось более кратко и понятно.
Теперь обратимся к диалоговому окну сохранения файла. Для его вызова достаточно переделать пример из листинга 2.23 следующим образом (листинг 2.25).
Листинг 2.25.
Окно сохранения файла
function ShowSave(strFilter: string; nFilterIndex: Integer = 0;
strInitFileName: string = \'\
strTitle: string = \'Сохранение файла\'):string;
var
ofn: OPENFILENAME;
begin
ZeroMemory(Addr(ofn), SizeOf(ofn));
//Формирование буфера (260 символов)
SetLength(strInitFileName, MAX_PATH);
PrepareFilterString(strFilter);
//Заполнение структуры для диалога
ofn.lStructSize := SizeOf(ofn);
ofn.hWndOwner := hParentWnd;
ofn.hInstance := hAppInst;
ofn.lpstrFilter := PAnsiChar(strFilter);
ofn.nFilterIndex := nFilterIndex;
ofn.lpstrFile := PAnsiChar(strInitFileName);
ofn.nMaxFile := MAX_PATH;
ofn.lpstrTitle := pAnsiChar(strTitle);
ofn.Flags := OFN_PATHMUSTEXIST or OFN_OVERWRITEPROMPT;
//Отображение окна диалога и обработка результата
if (GetSaveFileName(ofn) = True) then
ShowSave := ofn.lpstrFile;
end;
Здесь дополнительно к упомянутому ранее флaгyOFN_PATHMUSTEXIST применен флаг OFN_OVERWRI ТЕ PROMPT для того, чтобы при указании имени уже существующего файла был задан вопрос о желании пользователя заменить старый файл.
Окно выбора цвета
Вызов следующего диалогового окна – окна выбора цвета – приводится в листинге 2.26.
Листинг 2.26.
Окно выбора цвета
function ShowChooseColor(lastColor: COLORREF = 0):COLORREF;
var
choose: TChooseColor;
begin
ZeroMemory(Addr(choose), SizeOf(choose));
//Заполнение структуры для диалогового окна
choose.lStructSize := SizeOf(choose);
choose.hWndOwner := hParentWnd;
choose.hInstance := hAppInst;
choose.rgbResult := lastColor;
choose.lpCustColors := Addr(colors);
choose.Flags := CC_RGBINIT or CC_ANYCOLOR or CC_FULLOPEN;
//Отображение окна диалога и обработка результата
if (ChooseColor(choose) = True) then ShowChooseColor :=
choose.rgbResult
else ShowChooseColor := lastColor;
end;
Здесь также заполняется структура похожего назначения. Используются следующие флаги диалогового окна:
• CC_RGBINIT – использовать значение поля rgbResult в качестве предустановленного значения цвета (по умолчанию как ранее выбранного);
• CC_ANYCOLOR – отображать все доступные предопределенные цвета (левая часть, рис. 2.4);
• CC_FULLOPEN – раскрывать панель подбора цвета (правая часть, рис. 2.4).
Рис. 2.4. Окно выбора цвета
Поясним, что за переменная, а точнее, ее адрес, сохраняется в поле lpCustColors – это массив из 16 значений типа COLORREF:
colors: array [1..16] of COLORREF;
Обратите внимание на 16 квадратов в левой нижней области окна (рис. 2.4) – это места для определенных пользователем цветов. Для заполнения этой области окна и используются значения из массива colors. Массив может быть как локальным, так и глобальным (что удобнее, так как значения определенных пользователем цветов сохраняются между вызовами диалогового окна).