Windows Script Host для Windows 2000/XP

 //Преобразуем i-й символ в Windows-кодировку
 ss+=RusDict.Item(s.charAt(i));
 else ss+=s.charAt(i);
 }
 return ss;
}
/************* Начало *********************************************/
var s,ArrS,i; //Объявляем переменные
//Печатаем приглашение для ввода
WScript.StdOut.WriteLine("Вводите строки:");
s = WScript.StdIn.ReadAll; //Вводим строки с клавиатуры
WScript.StdOut.WriteBlankLines(3); //Печатаем пустые строки
ArrS=s.split("\n"); //Формируем массив из введенных строк
WScript.StdOut.WriteLine("Всего ведено строк: "+ArrS.length);
for (i=1;i<=ArrS.length;i++)
 //Преобразовываем введенные строки в Windows-кодировку
 //и выводим их на экран
 WScript.StdOut.WriteLine(i+": "+DosToWin(ArrS[i-1]));
/************* Конец *********************************************/

Листинг 2.17. Ввод нескольких строк с помощью метода StdIn.ReadAll (VBScript)

'*******************************************************************
' Имя: StdIn2.vbs
' Язык: VBScript
' Описание: Пример использования метода StdIn.ReadAll
'*******************************************************************
Option Explicit
' Функция для перевода строки из DOS- в Windows-кодировку
Function DosToWin(s)
Dim i,k,ss
 ss=""
 For i=1 To Len(s) ' Цикл по всем символам в строке
 k = Asc(Mid(s,i,1)) ' Определяем ANSI-код i-го символа
 ' Изменяем код k на код соответствующего символа в
 ' Windows-кодировке
 If (128 <= k) And (k <= 175) Then
 k=k+64
 ElseIf (224 <= k) And (k <= 239) Then
 k=k+16
 ElseIf k = 240 Then
 k=168
 ElseIf k = 241 Then
 k=184
 End If
 ss=ss+Chr(k)
 Next
 DosToWin=ss ' Возвращаем преобразованную строку
End Function
'************* Начало *********************************************
Dim s,ArrS,i,ColStr ' Объявляем переменные
' Печатаем приглашение для ввода
WScript.StdOut.WriteLine "Вводите строки:"
s = WScript.StdIn.ReadAll ' Вводим строки с клавиатуры
WScript.StdOut.WriteBlankLines 3 ' Печатаем пустые строки
ArrS=Split(s,vbCrLf) ' Формируем массив из введенных строк
ColStr=UBound(ArrS)+1
' Печатаем введенные строки
WScript.StdOut.WriteLine "Всего ведено строк: " & ColStr
For i=1 To ColStr
 ' Преобразовываем введенные строки в Windows-кодировку
 ' и выводим их на экран
 WScript.StdOut.WriteLine i & ": " & DosToWin(ArrS(i-1))
Next
'************* Конец *********************************************/

Ввод строк в графическом режиме

В сценариях VBScript в графическом режиме информацию можно вводить с помощью диалогового окна, создаваемого внутренней функцией InputBox (рис. 2.6).

Рис. 2.6. Диалоговое окно со строкой ввода

 Пример сценария, использующего функцию InputBox, представлен в листинге 2.18 (подробное описание параметров функции InputBox см. в приложении 1).

Листинг 2.18. Ввод одной строки с помощью функции InputBox (VBScript)

'*******************************************************************
' Имя: InpBox.vbs
' Язык: VBScript
' Описание: Пример использования функции InputBox
'*******************************************************************
Option Explicit
Dim s,s1 ' Объявляем переменные
s1="Пример" & vbCrLf & "диалогового окна" & vbCrLf & "для ввода строки"
' Выводим диалоговое окно со строкой ввода на экран
s=InputBox(s1,"Диалоговое окно VBScript")
' Выводим диалоговое окно с введенной строкой
MsgBox "Было введено: " & s
'************* Конец *********************************************/

К сожалению, ни в языке JScript, ни в объектной модели WSH нет функции или метода, позволяющих напрямую создавать диалоговые окна со строкой ввода. Однако при помощи файлов сценариев с XML-разметкой, описанных в главе 3, функции языка VBScript (InputBox в частности) можно использовать внутри JScript-сценария (соответствующий пример приведен в листинге 3.11).

Получение свойств WSH и запущенного сценария

На практике часто бывает необходимо знать определенные атрибуты WSH (например, с помощью какого приложения-сервера был запущен сценарий) и сценария, работающего в данный момент (например, имя этого сценария или путь к каталогу, в котором он находится). Некоторые параметры WSH и исполняемого сценария можно определить непосредственно с помощью соответствующих методов объекта WScript:

полный путь к приложению-серверу (cscript.exe или wscript.exe);