Язык программирования Perl

При необходимости можно объявить подпрограмму до ее использования (forward declaration), а определение ее отнести в конец программного файла. При объявлении тело подпрограммы не записывается. Например:

 sub factorial; # вычислить факториал числа

В объявлении подпрограмм могут указываться прототипы, о которых речь пойдет немного позднее в этой лекции.

Подпрограммы в Perl вызываются, когда их имя употребляется в каком-либо выражении. В этот момент выполняются определенные в подпрограмме действия, а выражение получает возвращенный подпрограммой результат. Хотя довольно часто возвращаемое подпрограммой значение игнорируется. Про такое обращение к подпрограмме говорят, что она вызвана в пустом контексте (void context). Минимальное выражение для вызова подпрограммы состоит из одного имени подпрограммы, и это выражение превращается в предложение программы, когда после него стоит точка с запятой. Вот пример выражения, состоящего только из вызова подпрограммы в пустом (безразличном) контексте:

 yellow_submarine('We all live in a');

Кстати, в пустом контексте можно употреблять любые другие выражения, хотя, конечно, смысл в этом есть далеко не всегда:

 2 * 2; # результат отброшен, есть смысл, если стоит...
 'Истина где-то рядом'; # ...в конце подпрограммы
 $x++; # используется ради побочного эффекта

Обращение к подпрограмме может записываться различными способами - главное, чтобы компилятор Рerl мог определить, что встретившийся идентификатор - это имя вызываемой подпрограммы. Дать подсказку об этом компилятору можно по-разному. В ранних версиях Perl при вызове перед именем подпрограммы требовался разыменовывающий префикс &. Например:

 &sub_without_parameters; # вызов подпрограммы без параметров
 &sub_with_parameters($arg1, $arg2); # и с параметрами

В современном Perl эта устаревшая форма вызова с префиксом & допустима и иногда используется. Гораздо чаще обращение к подпрограмме обозначается использованием круглых скобок после имени подпрограммы, даже если она вызывается без параметров. Как в этих примерах:

 format_c; # вызов подпрограммы без параметров
 format_text($text, $font, $size); # и с параметрами

Чтобы обращаться к пользовательской подпрограмме в стиле встроенных функций без круглых скобок, нужно чтобы определение или объявление подпрограммы было известно компилятору раньше ее вызова.

 sub circle; # объявление пользовательской функции
 $area_of_circle = circle $radius; # вызов функции

 sub circle { # определение пользовательской функции
 return 3.141592653*$_[0]*$_[0]; # площадь круга
 }

В Perl эффективно реализована рекурсия, поэтому традиционные рекурсивные алгоритмы можно оформлять в виде вызова в подпрограмме самой себя. Например, как в классической функции вычисления факториала:

 sub factorial ($) { # вычислить N!
 my $n = shift;
 return ($n <= 1) ? 1 : $n * factorial($n-1);
 }

Для разработки универсальных подпрограмм программисту нужно знать, в каком контексте была вызвана подпрограмма - какого возвращаемого значения от нее ожидают. Для этого в Perl предусмотрена функция wantarray. Она возвращает истинное значение, если подпрограмма вызвана в списочном контексте, ложное значение, если подпрограмма вызвана в скалярном контексте, и неопределенное значение, если подпрограмма вызвана в пустом контексте. Проверка ожидаемого значения в подпрограмме и примеры ее вызова могут выглядеть так:

 sub list_or_scalar {
 my @result = fill_result; # формируем результаты
 if (!defined wantarray) { # пустой контекст -
 return; # не возвращаем значения
} elsif (wantarray) { # списочный контекст -
 return @result; # возвращаем список
 } else { # скалярный контекст -
 return "@result"; # возвращаем скаляр
 }
 }
 list_or_scalar; # вызов в пустом контексте
 my @list = list_or_scalar; # вызов в списочном контексте
 my $scalar = list_or_scalar; # вызов в скалярном контексте

В Perl программисту предоставляется возможность выполнить во время компиляции ограниченную проверку количества и типов параметров у подпрограммы. Это делается с помощью прототипа списка параметров. Для этого в определении и в объявлении подпрограммы после ее имени в круглых скобках указывается прототип. Прототип представляет из себя последовательность разыменовывающих суффиксов, определяющих количество параметров подпрограммы и типы их контекстов. Вот несколько примеров определения подпрограмм с прототипами:

 # определение подпрограммы с 1-м параметром-скаляром
 sub list_mp3 ($) {
 my $path = $_[0];
 # ...
 }
 # определение подпрограммы c 2-мя скалярными параметрами
 sub translate ($$@) { # и списком скаляров
 my ($from_lang, $to_lang, @words) = @_;
 # ...
 }
 sub generate_test; # объявление подпрограммы без параметров

Для подпрограмм, определенных с прототипами, компилятор контролирует количество передаваемых аргументов и устанавливает ожидаемый подпрограммой контекст для каждого из аргументов. В приведенном далее вызове подпрограммы вместо массива ей будет передано количество элементов массива, поскольку прототип подпрограммы устанавливает скалярный контекст для единственного аргумента:

 list_mp3 @dirs; # будет передан 1 скаляр: scalar @dirs

Перечень символов, применяемых для описания прототипов, с примерами определения подпрограмм приведен в таблице 12.1.

Таблица 12.1. Обозначение прототипов подпрограмм

Прототип	Требования к параметрам	Пример определения / описания	Пример вызова
	отсутствие аргументов	sub mytime	mytime;
$	скалярное значение	sub myrand ($) sub myrename ($$)	myrand 100; myrename $old, $new;
@	список скалярных значений (поглощает остальные параметры, поэтому употребляется последним в списке)	sub myreverse (@) sub myjoin ($@)	myreverse $a, $b, $c; myjoin ':', $x, $y, $z;
&	подпрограмма	sub mygrep (&@)	mygrep {/pat/} $a, $b, $c;
*	элемент таблицы символов (например, дескриптор файла)	sub myopen (*$)	myopen HANDLE, $name;
\	взятие ссылки на следующий за ней прототип	sub mykeys (\%) sub mypop (\@) sub mypush(\@@)	mykeys %hash; mypop @array; mypush @stack, $a, $b;
;	разделитель обязательных параметров от необязательных (в конце списка)	sub mysubstr ($$;$)	mysubstr $str, $pos; mysubstr $str, $pos, $length;